***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 14, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-C75-AU A K 
.param
+vc0 = 7.046e-11		vc1 = 9.016e-12		vc2 = 1.000			vc3 = 1.083e-13		vc4 = 1.055e-1
+tc1 = 1.341e-2		tc2 = 2.301e-2		tc3 = 2.351e-2		tc4 = 2.811e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 3.096e-14		   n = 1.173		  rs = 3.925e-1
+ibv = 2.5e-3			 nbv = 1.0			  bv = 75
+ikf = 1.027e-1
***** capacitance parameter *****
+cjo = 9.775e-12		   m = 3.663e-1		  vj = 6.161e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.140		 xti = 3
+trs1 = 1.206e-3		trs2 = 5.703e-6		tikf = 1.0e-2
+tbv1 = 1.067e-3		tbv2 = -3.220e-7	
.ends BZT52-C75-AU
*$
